Summary

Collect CLI tool version information from Nextflow processes and collate it for MultiQC. Version strings are bash echo commands designed for use with Nextflow's eval output directive. They produce YAML-formatted lines that MultiQC can read directly. These helpers avoid the need to continuously and verbosely specify version strings in both script and stub blocks.

Get Started

Add the plugin to your Nextflow config:

plugins { id 'nf-versions' }

Examples

Version Functions in Nextflow Processes

include { bwaMem2Version; samtoolsVersion } from 'plugin/nf-versions'

process ALIGN {
    output:
    eval({bwaMem2Version()}), topic: "versions"
    eval({samtoolsVersion()}), topic: "versions"

    script:
    """
    bwa-mem2 mem ... | samtools sort ...
    """
}

Custom Python Libraries and Tools

Use pyPackageVersion() for custom Python tools or libraries:

include { pyPackageVersion } from 'plugin/nf-versions'

process SECRET_SAUCE {
    output:
    eval({pyPackageVersion("secret_sauce_lib")}), topic: "versions"

    script:
    """
    secret-sauce.py ...
    """
}

Custom R Libraries

Use rLibraryVersion() for R libraries, resolved with packageVersion():

include { rLibraryVersion } from 'plugin/nf-versions'

process RUN_ICHORCNA {
    output:
    eval({rLibraryVersion("ichorCNA")}), topic: "versions"

    script:
    """
    runIchorCNA.R ...
    """
}

Collating Versions for MultiQC

In your workflow, mix the versions topic channel through collateVersions() before passing to MultiQC:

include { MULTIQC } from './modules/multiqc'
include { collateVersions } from 'plugin/nf-versions'

workflow {
    // ... pipeline logic ... //

    def qc = channel.empty()
    qc = qc.mix(channel.topic("for_multiqc"))
    qc = qc.mix(collateVersions(channel.topic("versions")))

    MULTIQC(qc.collect())
}

Supported Tools

Plugin Function	Tool
bcftoolsVersion()	bcftools
bedtoolsVersion()	bedtools
bwaVersion()	bwa
bwaMem2Version()	bwa-mem2
falcoVersion()	falco
fastpVersion()	fastp
fastqcRsVersion()	fastqc-rs
fgbioVersion()	fgbio
mosdepthVersion()	mosdepth
picardVersion()	picard
revtagVersion()	revtag
sambambaVersion()	sambamba
samtoolsVersion()	samtools
splitcodeVersion()	splitcode

License

This plugin is published under the MIT license. Copyright © 2026 Fulcrum Genomics LLC.